From 40d5aad8feee2876ce0101d643027379c79aace3 Mon Sep 17 00:00:00 2001
From: Daniel Pouzzner <douzzer@wolfssl.com>
Date: Wed, 21 Apr 2021 17:28:27 -0500
Subject: [PATCH] configure.ac: improve dynamics of --enable-wolfsentry and
 --with-wolfsentry*, including existence-checking user-supplied paths.

---
 configure.ac | 78 ++++++++++++++++++++++++++++++++--------------------
 1 file changed, 48 insertions(+), 30 deletions(-)

diff --git a/configure.ac b/configure.ac
index e2678f8e7..b5115d440 100644
--- a/configure.ac
+++ b/configure.ac
@@ -2502,16 +2502,7 @@ then
 fi
 
 
-AC_ARG_ENABLE([wolfsentry],
-    [AS_HELP_STRING([--enable-wolfsentry],[Enable wolfSentry hooks and plugins (default: disabled)])],
-    [ ENABLED_WOLFSENTRY=$enableval ],
-    [ ENABLED_WOLFSENTRY=no ]
-    )
-
-if test "$ENABLED_WOLFSENTRY" = "yes"
-then
-    AM_CFLAGS="$AM_CFLAGS -DWOLFSSL_WOLFSENTRY_HOOKS -DHAVE_EX_DATA -DHAVE_EX_DATA_CLEANUP_HOOKS"
-fi
+ENABLED_WOLFSENTRY=no
 
 AC_ARG_WITH([wolfsentry],
     [AS_HELP_STRING([--with-wolfsentry=PATH],[PATH to directory with wolfSentry installation])],
@@ -2520,34 +2511,61 @@ AC_ARG_WITH([wolfsentry],
 
 AC_ARG_WITH([wolfsentry-lib],
     [AS_HELP_STRING([--with-wolfsentry-lib=PATH],[PATH to directory with wolfSentry library])],
-    [WOLFSENTRY_LIB=-L$withval],
+    [WOLFSENTRY_LIB=$withval],
     [WOLFSENTRY_LIB=""])
 
-if test "$WOLFSENTRY_LIB" = "" && test "$WOLFSENTRY_INSTALLDIR" != ""
+AC_ARG_WITH([wolfsentry-include],
+    [AS_HELP_STRING([--with-wolfsentry-include=PATH],[PATH to directory with wolfSentry header files])],
+    [WOLFSENTRY_INCLUDE=$withval],
+    [WOLFSENTRY_INCLUDE=""])
+
+if test -n "$WOLFSENTRY_INSTALLDIR" || test -n "$WOLFSENTRY_LIB" || test -n "$WOLFSENTRY_INCLUDE"
 then
-    WOLFSENTRY_LIB="-L${WOLFSENTRY_INSTALLDIR}/lib"
+    ENABLED_WOLFSENTRY=yes
+fi
+
+AC_ARG_ENABLE([wolfsentry],
+    [AS_HELP_STRING([--enable-wolfsentry],[Enable wolfSentry hooks and plugins (default: disabled)])],
+    [ ENABLED_WOLFSENTRY=$enableval ],
+    [ ]
+    )
+
+if test "$WOLFSENTRY_LIB" = "" && test -n "$WOLFSENTRY_INSTALLDIR"
+then
+    WOLFSENTRY_LIB="${WOLFSENTRY_INSTALLDIR}/lib"
+fi
+
+if test "$WOLFSENTRY_INCLUDE" = "" && test -n "$WOLFSENTRY_INSTALLDIR"
+then
+    WOLFSENTRY_INCLUDE="${WOLFSENTRY_INSTALLDIR}/include"
+fi
+
+if test -n "$WOLFSENTRY_LIB"
+then
+    AC_MSG_CHECKING([for $WOLFSENTRY_LIB])
+    if ! test -d "$WOLFSENTRY_LIB"
+    then
+        AC_MSG_ERROR([wolfSentry lib dir $WOLFSENTRY_LIB not found.])
+    fi
+    AC_MSG_RESULT([yes])
+    WOLFSENTRY_LIB="-L$WOLFSENTRY_LIB"
+fi
+
+if test -n "$WOLFSENTRY_INCLUDE"
+then
+    AC_MSG_CHECKING([for $WOLFSENTRY_INCLUDE])
+    if ! test -d "$WOLFSENTRY_INCLUDE"
+    then
+        AC_MSG_ERROR([wolfSentry include dir $WOLFSENTRY_INCLUDE not found.])
+    fi
+    AC_MSG_RESULT([yes])
+    WOLFSENTRY_INCLUDE="-I$WOLFSENTRY_INCLUDE"
 fi
 
 if test "$ENABLED_WOLFSENTRY" = "yes"
 then
+    AM_CFLAGS="$AM_CFLAGS -DWOLFSSL_WOLFSENTRY_HOOKS -DHAVE_EX_DATA -DHAVE_EX_DATA_CLEANUP_HOOKS"
     WOLFSENTRY_LIB="$WOLFSENTRY_LIB -lwolfsentry"
-else
-    WOLFSENTRY_LIB=""
-fi
-
-AC_ARG_WITH([wolfsentry-include],
-    [AS_HELP_STRING([--with-wolfsentry-include=PATH],[PATH to directory with wolfSentry header files])],
-    [WOLFSENTRY_INCLUDE=-I$withval],
-    [WOLFSENTRY_INCLUDE=""])
-
-if test "$WOLFSENTRY_INCLUDE" = "" && test "$WOLFSENTRY_INSTALLDIR" != ""
-then
-    WOLFSENTRY_INCLUDE="-I${WOLFSENTRY_INSTALLDIR}/include"
-fi
-
-if test "$ENABLED_WOLFSENTRY" != "yes"
-then
-    WOLFSENTRY_INCLUDE=""
 fi
 
 AC_SUBST([WOLFSENTRY_LIB])